Filter
Top Products
380
S:\agilent\8920\8920b\PRGGUIDE\BOOK\CHAPTERS\ibasic.fb
Chapter 7, IBASIC Controller
Method #1. Program Development on an External BASIC Language Computer
Uploading Programs from the Test Set to an External BASIC Controller through
GPIB
To upload a program from the Test Set to an external BASIC language controller
through GPIB the following program, which uses a command from the PROGram
subsystem to initiate the upload, must be running on the external BASIC language
controller. The uploaded program is stored to a file specified by the user.
In the following program the external BASIC language controller is a PC running
TransEra HT BASIC. The file is stored to the C:\HTB386 directory. If the external
BASIC language controller is an HP
®
9000 Series 200/300 Workstation, modify
the mass storage volume specifier appropriately. After running the program, the
uploaded program code will be in the designated file. Use the GET command to
retrieve the file for editing.
10 ! PROGRAM TO UPLOAD IBASIC CODE FROM TEST SET TO BASIC CONTROLLER THROUGH GPIB.
20 !######################################################################
30 !
40 ! The file for uploaded code will be "C:\htb386\code".
50 ! If you want to use a different file or directory, modify the two lines
60 ! with the labels "File_name_1" and "File_name_2".
70 !
80 !####################################################################
90 Addr=714 !Test Set GPIB address
100 ALLOCATE Line$[200]
110 PRINTER IS 1
120 CLEAR SCREEN
130 DISP "It may be several minutes before code begins transferring if the program is
long"
140 OUTPUT Addr;"*RST" !Reset the Test Set
150 OUTPUT Addr;"DISP TIB" !Displays the IBASIC screen
160 OUTPUT Addr;"PROG:EXEC ’CLS’" !Clears the Test Set display
170 OUTPUT 714;"PROG:DEF?" !Initiates the upload of whole program
180 ENTER Addr USING "X,D,#";Count_len !Number of lines in program
190 ENTER Addr USING VAL$(Count_len)&"D,#";Char_count !Number of characters
200 !
210 File_name_1: CREATE ASCII "C:\htb386\code",(1.05*Char_count/256)+5
220 ! Number of records reserved for upload.
230 File_name_2: ASSIGN @File TO "C:\htb386\code"
240 !
250 DISP "Transferring code from Test Set"
260 LOOP !Program transfer loop.
270 ENTER Addr;Line$ !CR/LF terminates each line.
280 PRINT Line$ !Displays new lines on Test Set display.
290 OUTPUT @File;Line$ !Transfer new line to file.
300 Char_count=Char_count-LEN(Line$)-2 !Reduces Char_count by the number of
310 ! characters in current line.
320 EXIT IF Char_count<=0
330 END LOOP
340 !
350 ASSIGN @File TO * !Cleans out file buffer.
360 ENTER Addr;Line$ !Close off reading
370 CLEAR SCREEN
380 DISP "Transfer complete."
390 LOCAL Addr
400 END